/*
    ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
    º           Gnork in Space 2         º
    ÇÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄĶ
    º Original concept and storyline by: º
    º         Valentijn Geirnaert        º
    º                                    º
    º           Programming by:          º
    º         Valentijn Geirnaert        º
    º                                    º
    º  All names, images and logos are   º
    º          legal property of:        º
    º         Valentijn Geirnaert        º
    ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
*/

//----------------------------------------
//  The Program Process, this is the main
//  process which loads all the graphics
//  and sounds, sets the resolution, etc..
//----------------------------------------

program Gnork_in_Space_2;

global
file_gnork;
file_enemy;
file_rock;
file_menu;

sound_shot_g;
sound_shot_e;
sound_explo;

font_gnorksmall;
font_gnork;
font_menu;
font_menusmall;

text_status;
text_game;
text_game2;

player;
enemy_id;
obstacle_id;

arrow;
menu_on=false;

enemies=0;
max_enemies;
total_enemies=0;

obstacles;

scroll1_speed=5;
scroll2_speed=3;

life=2;
shield=6;
score=0;
highscore=0;
level_clear;
ammo;
max_shot2_ammo=200;
max_shot3_ammo=10;
shot1_ammo=1;
shot2_ammo=0;
shot3_ammo=0;
level_cleared=false;
level=1;

godmode_on=false;

local
choice=0;

begin
    set_fps(24,0);
    set_mode(m1024x768);

    file_gnork=load_fpg("gnork\images\gnork.fpg");
    file_enemy=load_fpg("gnork\images\enemy.fpg");
    file_rock=load_fpg("gnork\images\rock.fpg");
    file_menu=load_fpg("gnork\images\menu.fpg");
    sound_shot_g=load_pcm("pcm\library\war\lasers\laser.pcm",0);
    sound_shot_e=load_pcm("pcm\library\war\lasers\laser2.pcm",0);
    sound_explo=load_pcm("pcm\library\war\explosio\explos00.pcm",0);
    font_gnork=load_fnt("gnork\images\gnork.fnt");
    font_gnorksmall=load_fnt("gnork\images\g_small.fnt");
    font_menu=load_fnt("gnork\images\g_menu.fnt");
    font_menusmall=load_fnt("gnork\images\gm_small.fnt");
    //load_pal("gnork\images\menu.pal");
    arrow=cursor(370,240);
    load("gnork.grk", & highscore);

end


//----------------------------------------
//  The cursor Process, this is the arrow
//  in the menu.
//----------------------------------------

process cursor(x,y);

private
change;
click;

begin
    change=load_pcm("pcm\library\buttons\buttons\boton00.pcm",0);
    click=load_pcm("pcm\library\buttons\buttons\boton01.pcm",0);
    load_pal("gnork\images\menu.pal");
    file=file_menu;
    graph=2;
    timer[8]=0;
    size=1;
    menu_on=true;
    // <menu stuff>
    delete_text(text_game);
    put_screen(file_menu,1);
    write(font_menu,532,350,4,"Gnork in Space 2");
    frame(2400);
    delete_text(all_text);
    write(font_menusmall,370,650,4,"Score:");
    write_int(font_menusmall,420,650,3,& score);
    write(font_menusmall,654,650,4,"Highscore:");
    write_int(font_menusmall,719,650,3,& highscore);
    write(font_menu,532,240,4,"New Game");
    write(font_menu,532,290,4,"Save Score");
    write(font_menu,532,340,4,"Clear Highscore");
    write(font_menu,532,390,4,"Help");
    write(font_menu,532,440,4,"Credits");
    write(font_menu,532,490,4,"Exit");
    sound(click,128,256);
    size=100;
    // </menu stuff>

    loop
        if(key(_up) and y>240 and timer[8]>10);
            y=y-50;
            choice=choice-1;
            timer[8]=0;
            sound(change,128,256);
        end
        if(key(_down) and y<490 and timer[8]>10);
            y=y+50;
            choice=choice+1;
            timer[8]=0;
            sound(change,128,256);
        end
        if(key(_enter) and timer[8]>30)
            timer[8]=0;
            switch(choice)
                case 0:
                    // <new game>
                    fade_off();
                    life=2;
                    level=1;
                    sound(click,128,256);
                    menu_on=false;
                    load_pal("gnork\images\gnork.pal");
                    delete_text(all_text);
                    timer[9]=0;
                    level_switch();
                end
                case 1:
                     sound(click,128,256);
                     highscore=score;
                     save("gnork.grk", & highscore, sizeof(highscore));
                end
                case 2:
                     sound(click,128,256);
                     highscore=0;
                     save("gnork.grk", & highscore, sizeof(highscore));
                end
                case 3:
                    sound(click,128,256);
                    size=1;
                    delete_text(all_text);
                    put_screen(file_menu,1);
                    write(font_menu,552,200,4,"Gnork Help");
                    write(font_menu,552,250,4,"Use the arrow keys to move");
                    write(font_menu,552,280,4,"Use the space bar to shoot");
                    write(font_menu,552,330,4,"Use [1], [2] and [3] to select a weapon");
                    write(font_menu,552,360,4,"Press [ESC] to exit the game");
                    write(font_menu,552,410,4,"Press [ENTER] to return to the menu");
                    write(font_menusmall,532,650,4,"visit Gnork at: http://www.planetgnork.tk");
                    if(scan_code==0);
                        frame;
                    else
                        sound(click,128,256);
                        size=100;
                        delete_text(all_text);
                        write(font_menusmall,370,650,4,"Score:");
                        write_int(font_menusmall,420,650,3,& score);
                        write(font_menusmall,654,650,4,"Highscore:");
                        write_int(font_menusmall,719,650,3,& highscore);
                        write(font_menu,532,240,4,"New Game");
                        write(font_menu,532,290,4,"Save Score");
                        write(font_menu,532,340,4,"Clear Highscore");
                        write(font_menu,532,390,4,"Help");
                        write(font_menu,532,440,4,"Credits");
                        write(font_menu,532,490,4,"Exit");

                    end
                end
                case 4:
                    sound(click,128,256);
                    size=1;
                    delete_text(all_text);
                    put_screen(file_menu,1);
                    write(font_menu,552,200,4,"Gnork in Space 2");
                    write(font_menu,552,250,4,"Original Concept and Story line:");
                    write(font_menu,552,280,4,"Valentijn Geirnaert");
                    write(font_menu,552,330,4,"Programming:");
                    write(font_menu,552,360,4,"Valentijn Geirnaert");
                    write(font_menu,552,410,4,"Graphics:");
                    write(font_menu,552,440,4,"Valentijn Geirnaert");
                    write(font_menu,552,490,4,"Copyright Valentijn Geirnaert 2002");
                    write(font_menusmall,532,650,4,"visit Gnork at: http://www.planetgnork.tk");
                    if(scan_code==0);
                        frame;
                    else
                        sound(click,128,256);
                        size=100;
                        delete_text(all_text);
                        write(font_menusmall,370,650,4,"Score:");
                        write_int(font_menusmall,420,650,3,& score);
                        write(font_menusmall,654,650,4,"Highscore:");
                        write_int(font_menusmall,719,650,3,& highscore);
                        write(font_menu,532,240,4,"New Game");
                        write(font_menu,532,290,4,"Save Score");
                        write(font_menu,532,340,4,"Clear Highscore");
                        write(font_menu,532,390,4,"Help");
                        write(font_menu,532,440,4,"Credits");
                        write(font_menu,532,490,4,"Exit");

                    end
                end
                case 5:
                    sound(click,128,256);
                    frame(1200);
                    fade_off();
                    exit("Thanks for playing Gnork in Space 2. Be sure to check for new versions on: http://www.planetgnork.tk .",0);
                end
            end
        end
        frame;
    end
end


//----------------------------------------
//  The Gnork Process, this is the player.
//----------------------------------------

process gnork(x,y);

private
weapon=1;

begin
    ammo=shot1_ammo;
    file=file_gnork;
    load_pal("gnork\images\gnork.pal");
    graph=5;
    timer[0]=0;
    //gnork_shield(x,y+3);
    signal(arrow, s_kill);
    loop
        if(key(_g) and key(_u) and key(_n));
            shot2_ammo=+50;
            shot3_ammo=+50;
        end
        if(key(_a) and key(_m) and key(_o));
            ammo=ammo+50;
        end
        if(key(_1));
            weapon=1;
            ammo=shot1_ammo;
        end
        if(key(_2));
            ammo=shot2_ammo;
            weapon=2;
        end
        if(key(_3));
            weapon=3;
            ammo=shot3_ammo;
        end
        // <codes>
        if(key(_m) and key(_e) and key(_g) and key(_o) and key(_d));
            godmode_on=true;
        end
        // </codes>
        // <ship control stuff>
        if(key(_right) and x<1024);
            x=x+10;
            scroll.x1-=1;
        end
        if(key(_left) and x>0);
            x=x-10;
            scroll.x1+=1;
        end
        if(key(_up) and y>620);
            y=y-5;;
        end
        if(key(_down) and y<710);
            y=y+5;;
        end

        if(key(_space));
            switch(weapon);
                case 1:
                    if(timer>50)
                        shot1(x,y,-90000);
                        shot1(x,y,-90000);
                        shot1(x,y,-90000);
                        sound(sound_shot_g,60,256);
                        timer[0]=0;
                    end
                end
                case 2:
                    ammo=shot2_ammo;
                    if(timer[0]>30);
                        if(shot2_ammo>0);
                            shot2(x-15,y+10,rand(-45000,45000));
                            shot2(x-15,y+10,rand(-45000,45000));
                            shot2(x+15,y+10,rand(-45000,45000));
                            shot2(x+15,y+10,rand(-45000,45000));
                            sound(sound_shot_g,60,240);
                            sound(sound_shot_g,60,260);
                            shot2_ammo=shot2_ammo-2;
                            timer[0]=0;
                        else
                            weapon=1;
                        end
                    end
                end
                case 3:
                    ammo=shot3_ammo;
                    if(timer[0]>100);
                        if(shot3_ammo>0);
                            clusterbomb(x,y,rand(-45000,45000));
                            sound(sound_shot_g,60,256);
                            shot3_ammo=shot3_ammo-1;
                            timer[0]=0;
                        else
                            weapon=2;
                        end
                    end
                end
            end

        end
        // </ship control stuff>
        if(collision(type enemy1) and godmode_on==false);
            shield=shield-2;
        end
        if(shield<0)
            shield=0;
            life--;
            if(life<0);
                sound(sound_explo,100,200);
                explosion(x,y,rand(90,110),rand(-45000,45000));
                size=1;
                delete_text(all_text);
                text_game=write(font_gnork,512,384,4,"Game over!");
                scroll1_speed=0;
                scroll2_speed=0;
                signal(enemy_id, s_freeze_tree);
                signal(obstacle_id, s_freeze_tree);
                frame(2400);
                fade_off();
                    load_pal("gnork\images\menu.pal");
                    stop_scroll(0);
                    signal(player, s_kill_tree);
                    signal(enemy_id, s_kill_tree);
                    signal(obstacle_id, s_kill_tree);
                    arrow=cursor(380,240);
                fade_on();
            else
                sound(sound_explo,100,200);
                explosion(x,y,rand(90,110),rand(-45000,45000));
                size=1;
                text_game=write(font_gnork,512,384,4,"You died!");
                scroll1_speed=0;
                scroll2_speed=0;

                signal(enemy_id, s_freeze_tree);
                signal(obstacle_id, s_freeze_tree);
                frame(2400);
                fade_off();
                    delete_text(text_game);
                    x=512;
                    y=668;
                    shield=6;
                    weapon=1;
                    enemies=0;
                    ammo=0;
                    shot2_ammo=0;
                    shot3_ammo=0;
                    size=100;
                    signal(enemy_id, s_kill_tree);
                    signal(obstacle_id, s_kill_tree);
                    enemy_id=call_enemy1(10);
                    obstacle_id=call_obstacle(1);
                    scroll1_speed=5;
                    scroll2_speed=3;
                    start_scroll(0,file_gnork,2,1,0,15);
                fade_on();
            end
         end
        frame;
    end
end


//----------------------------------------
//  The call_gnork Process, this is used
//  to avoid any nasty stack overflow.
//----------------------------------------

process call_gnork();

begin
    player=gnork(512,668);
    frame;
end


//----------------------------------------
//  The shot1 Process, the first weapon.
//  Lasergun; fires a laserblast at the
//  eneny. Uses 1 ammo.
//----------------------------------------

process shot1(x,y,angle);

begin
    file=file_gnork;
    graph=6;
    z=-1;
    repeat
        advance(-25);
        if(collision(type enemy1));
            //if(reserved.id_scan <> player);
               // signal(reserved.id_scan,s_kill);
                break;
           // end
        end
        frame;
    until(y<-10 or y>800 or x<0 or x>1030);
end


//----------------------------------------
//  The shot2 Process, the second weapon.
//  Plasma cannon; fires two plasmaballs
//  at the enemy. Uses 2 ammo.
//----------------------------------------

process shot2(x,y,angle);

begin
    priority=10;
    file=file_gnork;
    graph=7;
    z=-2;
    repeat
        y=y-20;
        angle=angle+11250;
        if(collision(type enemy1));
            break;
        end
        frame;
   until(y<-10);
end


//----------------------------------------
//  The clusterbomb Process, this is the
//  clusterbomb.
//----------------------------------------

process clusterbomb(x,y,angle);

begin
    priority=10;
    file=file_gnork;
    graph=9;
    z=-2;
    timer[3]=0;
    loop
        y=y-15;
        angle=angle+11250;
        if(timer[3]>33);
            shot1(x,y,-90000);
            shot1(x,y,-90000);
            shot1(x,y,0);
            shot1(x,y,0);
            shot1(x,y,-45000);
            shot1(x,y,-45000);
            shot1(x,y,-135000);
            shot1(x,y,-135000);
            shot1(x,y,-180000);
            shot1(x,y,-180000);
            shot1(x,y,-225000);
            shot1(x,y,-225000);
            shot1(x,y,45000);
            shot1(x,y,45000);
            timer[3]=0;
        end
        if(y<350 or collision(type enemy1));
            shot1(x,y,-90000);
            shot1(x,y,-90000);
            shot1(x,y,0);
            shot1(x,y,0);
            shot1(x,y,-45000);
            shot1(x,y,-45000);
            shot1(x,y,-135000);
            shot1(x,y,-135000);
            shot1(x,y,-180000);
            shot1(x,y,-180000);
            shot1(x,y,-225000);
            shot1(x,y,-225000);
            shot1(x,y,45000);
            shot1(x,y,45000);
            break;
        end
        frame;
    end
end

//----------------------------------------
//  The call_enemy Process, this summons
//  all enemy processes and checks if a
//  level is cleared.
//----------------------------------------

process call_enemy1(amount);

begin
    loop
        if(rand(0,100)<amount and enemies<11);
            enemy1(rand(20,1000),rand(5,8));
            enemies++;
            level_clear=((total_enemies*100)/max_enemies);
            if(level_clear>99 or (key(_n) and key(_e) and key(_x) and key(_t)));
                switch(level)
                    case 1:
                        text_game=write(font_gnork,512,384,4,"Level 1 Cleared!");
                    end
                    case 2:
                        text_game=write(font_gnork,512,384,4,"Level 2 Cleared!");
                    end
                    case 3:
                        text_game=write(font_gnork,512,384,4,"Level 3 Cleared! Demo has ended. Press [ESC].");
                    end
                end
                level_clear=100;
                break;
            end
        end
        frame;
    end
    frame(4800);
    loop
        player.y=player.y-10;
        frame;
        if(player.y<-100);
            break;
        end
    end
    fade_off();
    level++;
    level_switch();
end


//----------------------------------------
//  The call_obstace Process, this summons
//  all the obstacels.
//----------------------------------------

process call_obstacle(amount);

begin
    loop
        if(rand(0,200)<amount and obstacles<4);
            obstacle(rand(20,1000),rand(3,8),rand(-45000,45000),rand(50,100));
            obstacles++;
        end
        if(level_clear>99);
            break;
        end
        frame;
    end
end

//----------------------------------------
//  The enemy1 Process, here is the code
//  for all the normal enemies.
//----------------------------------------

process enemy1(x,speed);

begin
    file=file_enemy;
    z=1;
    priority=1;
    switch(level)
        case 1:
            graph=3;
            loop
                y=y+speed;
                if(y>800);
                    break;
                end
                if(id.x-player.x>-15 and id.x-player.x<15);
                    graph=4;
                    speed=20+rand(5,8);
                else
                    if(id.x<player.x);
                        x=x+1;
                    else
                        x=x-1;
                    end
                end
                if(collision(type gnork) and godmode_on==false)
                    shield=shield-2;
                    sound(sound_explo,100,200);
                    explosion(x,y,rand(90,110),rand(-45000,45000));
                    break;
                end
                if(collision(type shot1) or collision(type shot2));
                    if(rand(1,5)>3);
                        pickup(x,y,rand(1,50));
                    end
                    sound(sound_explo,100,200);
                    explosion(x,y,rand(90,110),rand(-45000,45000));
                    score=score+5;
                    break;
                end
                frame;
            end
            enemies--;
            total_enemies++;
        end
        case 2:
            graph=1;
            timer[1]=0;
            loop
                y=y+speed;
                if(y>800);
                    enemies--;
                    total_enemies++;
                    break;
                end
                if(id.x-player.x>-22 and id.x-player.x<22 and timer[1]>30 and player.y-id.y>150);
                    sound(sound_shot_e,128,rand(200,300));
                    enemy_shot(x,y-10);
                    timer[1]=0;
                end
                if(collision(type shot1) or collision(type shot2));
                    if(rand(1,5)>3);
                        pickup(x,y,rand(1,50));
                    end

                    sound(sound_explo,100,200);
                    explosion(x,y,rand(90,110),rand(-45000,45000));
                    enemies--;
                    total_enemies++;
                    score=score+5;
                    break;
                end
                if(collision(type gnork) and godmode_on==false)
                    shield=shield-2;
                    sound(sound_explo,100,200);
                    explosion(x,y,rand(90,110),rand(-45000,45000));
                    enemies--;
                    total_enemies++;
                    break;
                end
                frame;
            end
        end
        case 3:
            graph=5;
            timer[2]=0;
            loop
                y=y+speed;
                if(y>800);
                    enemies--;
                    total_enemies++;
                    break;
                end
                if(player.y-id.y>450);
                    if(id.x<player.x);
                        x=x+5;
                    else
                        x=x-5;
                    end
                end
                if(id.x-player.x>-22 and id.x-player.x<22 and timer[2]>50 and player.y-id.y>300);
                    sound(sound_shot_e,128,rand(200,300));
                    enemy_shot2(x-10,y-5);
                    enemy_shot2(x+10,y-5);
                    timer[2]=0;
                end
                if(collision(type shot1) or collision(type shot2));
                    if(rand(1,5)>3);
                        pickup(x,y,rand(1,50));
                    end

                    sound(sound_explo,100,200);
                    explosion(x,y,rand(90,110),rand(-45000,45000));
                    enemies--;
                    total_enemies++;
                    score=score+5;
                    break;
                end
                if(collision(type gnork) and godmode_on==false)
                    shield=shield-2;
                    sound(sound_explo,100,200);
                    explosion(x,y,rand(90,110),rand(-45000,45000));
                    enemies--;
                    total_enemies++;
                    break;
                end
                frame;
            end
        end
        case 4;
            graph=11;
            turret_head();

            loop
                y=y+speed;
                if(y>800);
                    enemies--;
                    total_enemies++;
                    break;
                end
                frame;
            end
        end
    end
end


//----------------------------------------
//  The turret_head process, this is the
//  moving turret, shooting at gnork
//----------------------------------------

process turret_head();

begin
    file=file_enemy;
    graph=12;
    timer[2]=0;
    loop
        x=father.x;
        y=father.y;
        if(get_dist(player)<600);
            angle=get_angle(player);
            if(timer[2]>100);
                sound(sound_shot_e,128,rand(200,300));
                enemy_shot3(x,y,angle);
                enemy_shot3(x,y,angle);
                timer[2]=0;
            end
        end
        if(collision(type shot1) or collision(type shot2));
            if(rand(1,5)>3);
                pickup(x,y,rand(1,50));
            end
            sound(sound_explo,100,200);
            explosion(x,y,rand(90,110),rand(-45000,45000));
            score=score+5;
            break;
        end
        if(collision(type gnork));
            shield-=2;
            sound(sound_explo,100,200);
            explosion(x,y,rand(90,110),rand(-45000,45000));
        end
        if(y>800);
            break;
        end
        frame;
    end
end


//----------------------------------------
//  The enemy_shot Process, the enemy uses
//  this process as gnork uses the shot
//  process
//----------------------------------------

process enemy_shot(x,y)

begin
    file=file_enemy;
    graph=99;
    repeat
        y=y+17;
        if(collision(type gnork)and godmode_on==false);
            shield=shield-1;
            break;
        end
        frame;
    until(y>800);
end


//-----------------------------------------
//  The obstacel Process, this makes the
//  obstacles in the levels (asteroids,etc)
//-----------------------------------------

process obstacle(x,speed,angle,size)

begin
    file=file_rock;
    z=-4;
    switch(level)
        case 1:
            graph=19;
            loop
                y=y+speed;
                graph++;
                if(graph==38);
                    graph=19;
                end
                if(y>800);
                    obstacles--;
                    break;
                end
                if(collision(type gnork)and godmode_on==false);
                    shield=shield-7;
                end
                frame;
            end
        end
    end
end


//-----------------------------------------
//  The enemy_shot2 Process, the enemy uses
//  this process as gnork uses the shot
//  process
//-----------------------------------------

process enemy_shot3(x,y,angle)

begin
    file=file_enemy;
    graph=14;
    repeat
        advance(20);
        if(collision(type gnork)and godmode_on==false);
            shield=shield-1;
            break;
        end
        frame;
    until(y>800);
end


//-----------------------------------------
//  The enemy_shot3 Process, the enemy uses
//  this process as gnork uses the shot
//  process
//-----------------------------------------

process enemy_shot2(x,y)

begin
    file=file_enemy;
    graph=98;
    repeat
        y=y+25;
        if(collision(type gnork)and godmode_on==false);
            shield=shield-1;
            break;
        end
        frame;
    until(y>800);
end

//----------------------------------------
//  The explosion Process, this shows the
//  explosion after a hit, but makes sure
//  you only need to type it once
//----------------------------------------

process explosion(x,y,size,angle);

begin
    file=file_rock;
    from graph=1 to 11;
        frame;
    end
end


//----------------------------------------
//  The jet Process, this shows the jet
//  flame behind the crafts.
//----------------------------------------

process jet(x,y,flags);

begin
    z=-3;
    file=file_rock;
    graph=12;
    y=father.y-18;
    frame;
end

//----------------------------------------
//  The shield Process, this is the shield
//  that you see around Gnork.
//----------------------------------------

process gnork_shield(x,y)

private
teller=-1;

begin
    file=file_gnork;
    graph=8;
    flags=4;
    loop
        size=100+teller;
        x=father.x;
        y=father.y;
        switch(size)
            case 96:
                teller=1;
            end
            case 104:
                teller=-1;
            end
        end
        frame;
    end
end


//---------------------------------------
//  The pickup Process, these are the
//  pick ups
//---------------------------------------

process pickup(x,y,mode);

begin
    file=file_enemy;
    switch(mode)
        case 1..34:
            graph=97;
            repeat
                y=y+10;
                if(collision(type gnork));
                    shot2_ammo=shot2_ammo+30;
                    if(shot2_ammo>max_shot2_ammo);
                        shot2_ammo=max_shot2_ammo;
                    end
                    break;
                end
                frame;
            until(y>800);
        end
        case 41..49:
            graph=96;
            repeat
                y=y+10;
                if(collision(type gnork));
                    shield=shield+6;
                    if(shield>6);
                        shield=6;

                    end
                    break;
                end
                frame;
            until(y>800);

        end
        case 50:
            graph=95;
            repeat
                y=y+10;
                if(collision(type gnork));
                    life=life+1;
                    break;
                end

                frame;
            until(y>800);
        end
        case 35..40:
            graph=94;
            repeat
                y=y+10;
                if(collision(type gnork));
                    shot3_ammo=shot3_ammo+1;
                    if(shot3_ammo>max_shot3_ammo);
                        shot3_ammo=max_shot3_ammo;
                    end
                    break;
                end
                frame;
            until(y>800);
        end
    end
end


//----------------------------------------
//  The switch_level Process. This makes
//  it easy to change the level if needed.
//----------------------------------------

process level_switch();

begin
    delete_text(all_text);
    file=file_menu;
    signal(arrow, s_kill);
    switch(level)
        // <level 1>
        case 1:

                delete_text(all_text);
                load_pal("gnork\images\gnork.pal");

                obstacle_id=call_obstacle(1);
                max_enemies=100;
                start_scroll(0,file_gnork,2,1,0,15);
                call_gnork();
                enemy_id=call_enemy1(10);
                shield=6;
                score=0;
                total_enemies=0;
                scroll1_speed=4;
                scroll2_speed=2;
                text_game=write(font_gnork,512,384,4,"Stage 1 - Level 1");
                write(font_gnorksmall,80,50,5,"Shield:");
                write_int(font_gnorksmall,100,50,3,& shield);
                write(font_gnorksmall,80,100,5,"Ammo:");
                write_int(font_gnorksmall,100,100,3,& ammo);
                write(font_gnorksmall,80,150,5,"Life:");
                write_int(font_gnorksmall,100,150,3,& life);
                write(font_gnorksmall,910,50,5,"Level cleared:");
                write_int(font_gnorksmall,920,50,3,& level_clear);
                write(font_gnorksmall,950,50,3,"%");
                write(font_gnorksmall,910,100,5,"Score:");
                write_int(font_gnorksmall,920,100,3,& score);
                frame(1200);
                timer[9]=0;
                fade_on();
            loop
                scroll.y0=scroll.y0-scroll1_speed;
                scroll.y1=scroll.y1-scroll2_speed;
                if(key(_esc) and menu_on<>true);
                    fade_off();
                        load_pal("gnork\images\menu.pal");
                        stop_scroll(0);
                        signal(player, s_kill_tree);
                        signal(enemy_id, s_kill_tree);
                        signal(obstacle_id, s_kill_tree);
                        delete_text(all_text);
                        arrow=cursor(380,240);
                    fade_on();
                end
                if(timer[9]>300 and timer[9]<400);
                    delete_text(text_game);

                end
                frame;
            end
        end
        // </level 1>
        // <level 2>
        case 2:
                delete_text(all_text);
                load_pal("gnork\images\gnork.pal");
                signal(enemy_id, s_kill_tree);
                signal(player, s_kill_tree);
                signal(obstacle_id, s_kill_tree);
                call_gnork();
                enemy_id=call_enemy1(10);
                obstacle_id=call_obstacle(1);
                max_enemies=100;
                start_scroll(0,file_gnork,2,1,0,15);

                shield=6;
                total_enemies=0;
                scroll1_speed=4;
                scroll2_speed=2;
                total_enemies=0;
                text_game=write(font_gnork,512,384,4,"Stage 1 - Level 2");
                write(font_gnorksmall,80,50,5,"Shield:");
                write_int(font_gnorksmall,100,50,3,& shield);
                write(font_gnorksmall,80,100,5,"Ammo:");
                write_int(font_gnorksmall,100,100,3,& ammo);
                write(font_gnorksmall,80,150,5,"Life:");
                write_int(font_gnorksmall,100,150,3,& life);
                write(font_gnorksmall,910,50,5,"Level cleared:");
                write_int(font_gnorksmall,920,50,3,& level_clear);
                write(font_gnorksmall,950,50,3,"%");
                write(font_gnorksmall,910,100,5,"Score:");
                write_int(font_gnorksmall,920,100,3,& score);

                //frame(1200);
                timer[9]=0;
            fade_on();
            loop
                scroll.y0=scroll.y0-scroll1_speed;
                scroll.y1=scroll.y1-scroll2_speed;
                if(key(_esc));
                    fade_off();
                        load_pal("gnork\images\menu.pal");
                        stop_scroll(0);
                        signal(player, s_kill_tree);
                        signal(enemy_id, s_kill_tree);
                        signal(obstacle_id, s_kill_tree);
                        delete_text(all_text);
                        arrow=cursor(380,240);
                    fade_on();
                end
                if(timer[9]>300 and timer[9]<400);
                    delete_text(text_game);
                end
                frame;
            end
        end
        // </level 2>
        // <level 3>
        case 3:
                delete_text(all_text);
                load_pal("gnork\images\gnork.pal");
                signal(enemy_id, s_kill_tree);
                signal(player, s_kill_tree);
                signal(obstacle_id, s_kill_tree);
                call_gnork();
                enemy_id=call_enemy1(10);
                obstacle_id=call_obstacle(1);
                max_enemies=100;
                start_scroll(0,file_gnork,2,1,0,15);
                shield=6;
                total_enemies=0;
                scroll1_speed=4;
                scroll2_speed=2;
                total_enemies=0;
                text_game=write(font_gnork,512,384,4,"Stage 1 - Level 3");
                write(font_gnorksmall,80,50,5,"Shield:");
                write_int(font_gnorksmall,100,50,3,& shield);
                write(font_gnorksmall,80,100,5,"Ammo:");
                write_int(font_gnorksmall,100,100,3,& ammo);
                write(font_gnorksmall,80,150,5,"Life:");
                write_int(font_gnorksmall,100,150,3,& life);
                write(font_gnorksmall,910,50,5,"Level cleared:");
                write_int(font_gnorksmall,920,50,3,& level_clear);
                write(font_gnorksmall,950,50,3,"%");
                write(font_gnorksmall,910,100,5,"Score:");
                write_int(font_gnorksmall,920,100,3,& score);

                //frame(1200);
                timer[9]=0;
            fade_on();
            loop
                scroll.y0=scroll.y0-scroll1_speed;
                scroll.y1=scroll.y1-scroll2_speed;
                if(key(_esc));
                    fade_off();
                        load_pal("gnork\images\menu.pal");
                        stop_scroll(0);
                        signal(player, s_kill_tree);
                        signal(enemy_id, s_kill_tree);
                        signal(obstacle_id, s_kill_tree);
                        delete_text(all_text);
                        arrow=cursor(380,240);
                    fade_on();
                end
                if(timer[9]>300 and timer[9]<400);
                    delete_text(text_game);
                end
                frame;
            end
        end
    end
end